nix-config/modules/home/home/default.nix

{
  config,
  lib,
  pkgs,
  namespace,
  hasDestopEnvironment ? true,
  system,
  ...
}:
let
  inherit (lib.${namespace}) enabled;
  isArm = ("aarch64-linux" == system) || ("aarch64-darwin" == system);
  # Non-login / system accounts (root, nixos installer, etc.) should not get
  # desktop packages, tmux, nh, kdeconnect, nextcloud-client, etc.
  # Detect them by username so individual host home files are not needed.
  isSystemUser = lib.elem config.home.username [
    "root"
    "nixos"
  ];
in
{
  home = {
    enableNixpkgsReleaseCheck = lib.mkDefault false;
    homeDirectory = lib.mkDefault (
      if config.home.username == "root" then "/root" else "/home/${config.home.username}"
    );
    packages =
      with pkgs;
      (
        if isSystemUser then
          [ ]
        else
          [
            age
            clinfo
            cpufetch
            dbus
            deadnix
            lm_sensors
            nano
            nebula
            nix-prefetch-scripts
            nixfmt
            pciutils
            proton-pass-cli
            proton-vpn-cli
            proton-vpn
            protonup-ng
            rsync
            smartmontools
            sops
            tailscale
            tree
            usbutils
            vim
            vulkan-tools
            wget
          ]
          ++ (
            if hasDestopEnvironment then
              [
                boxbuddy
                cider-2
                stable.chromium
                firefox
                gamescope
                gamescope-wsi
                gparted
                mission-center
                parted
                vesktop
              ]
              ++ (
                if isArm then
                  [ ]
                else
                  [
                    proton-pass
                  ]
              )
            else
              [ ]
          )
      );

    file = {
      ".face".source = "${pkgs.${namespace}.profile-pic}/profile-pic";
    };

    stateVersion = lib.mkDefault "23.11";
  };

  programs = {
    # nix-index-database is not available in all home configs (e.g. iso-minimal
    # standalone homes don't load the nix-index-database HM module).
    # Set it per-host in homes that explicitly load the module.
    btop = {
      enable = lib.mkDefault (!isSystemUser);
      package = pkgs.btop;
    };
    fastfetch.enable = lib.mkDefault (!isSystemUser);
    home-manager = lib.mkDefault enabled;
    java.enable = lib.mkDefault (!isSystemUser);
    mangohud.enable = lib.mkDefault (hasDestopEnvironment && !isSystemUser);
    password-store.enable = lib.mkDefault (!isSystemUser);
    nh = {
      enable = lib.mkDefault (!isSystemUser);
      flake = "/etc/nixos";
      clean = {
        enable = lib.mkDefault (!isSystemUser);
        extraArgs = "--keep 5";
      };
    };

    micro = {
      enable = lib.mkDefault true;
      settings = {
        autoindent = true;
        autosu = true;
        eofnewline = true;
        tabsize = 4;
        tabstospaces = true;
      };
    };

    tmux = {
      enable = lib.mkDefault (!isSystemUser);
      terminal = "screen-256color";
      sensibleOnTop = true;
      focusEvents = true;
      newSession = true;
      mouse = true;
      plugins = with pkgs; [
        tmuxPlugins.cpu
        {
          plugin = tmuxPlugins.resurrect;
          extraConfig = "set -g @resurrect-strategy-nvim 'session'";
        }
        {
          plugin = tmuxPlugins.continuum;
          extraConfig = ''
            set -g @continuum-restore 'on'
            set -g @continuum-save-interval '60' # minutes
          '';
        }
        tmuxPlugins.better-mouse-mode
      ];
      extraConfig = ''
        set -g status-right '#[fg=black,bg=color15] #{cpu_percentage}  %H:%M '
        run-shell ${pkgs.tmuxPlugins.cpu}/share/tmux-plugins/cpu/cpu.tmux
        set -g default-terminal "xterm-256color"
        set -ga terminal-overrides ",*256col*:Tc"
        set -ga terminal-overrides '*:Ss=\E[%p1%d q:Se=\E[ q'
        set-environment -g COLORTERM "truecolor"

        # Mouse works as expected
        set-option -g mouse on
        # easy-to-remember split pane commands
        bind | split-window -h -c "#{pane_current_path}"
        bind - split-window -v -c "#{pane_current_path}"
        bind c new-window -c "#{pane_current_path}"
      '';
    };
  };

  services = {
    # nextcloud-client is disabled by default for all users; systems that
    # want it enabled must opt in explicitly in their home configuration.
    nextcloud-client.enable = lib.mkDefault false;
    pass-secret-service.enable = lib.mkDefault (!isSystemUser);
    kdeconnect = {
      enable = lib.mkDefault (hasDestopEnvironment && !isSystemUser);
      indicator = lib.mkDefault (hasDestopEnvironment && !isSystemUser);
      package = pkgs.kdePackages.kdeconnect-kde;
    };
  };
}