{
  buildHomeAssistantComponent,
  fetchFromGitHub,
  home-assistant,
  ...
}:
buildHomeAssistantComponent rec {
  owner = "moralmunky";
  domain = "mail_and_packages";
  version = "0.5.0";

  src = fetchFromGitHub {
    owner = owner;
    repo = "Home-Assistant-Mail-And-Packages";
    tag = version;
    hash = "sha256-Am3EYkSYCQuYJmm6xdUwCa0h/ldk4hwTxRTxc0BU2j8=";
  };

  nativeBuildInputs = with home-assistant.python.pkgs; [
    aioimaplib
    beautifulsoup4
    dateparser
    pillow
  ];

  propagatedBuildInputs = with home-assistant.python.pkgs; [
    aioimaplib
  ];

  postPatch = ''
    substituteInPlace custom_components/mail_and_packages/const.py \
      --replace-fail 'DEFAULT_PATH = "custom_components/mail_and_packages/images/"' \
                    'DEFAULT_PATH = "/var/lib/homeassistant/images/"' \
      --replace-fail 'DEFAULT_STORAGE = "custom_components/mail_and_packages/images/"' \
                    'DEFAULT_STORAGE = "/var/lib/homeassistant/images/"' \
      --replace-fail 'DEFAULT_CUSTOM_IMG_FILE = "custom_components/mail_and_packages/images/mail_none.gif"' \
                    'DEFAULT_CUSTOM_IMG_FILE = "/var/lib/homeassistant/images/mail_none.gif"'

    substituteInPlace custom_components/mail_and_packages/helpers.py \
      --replace-fail 'return "custom_components/mail_and_packages/images/"' \
                    'return "/var/lib/homeassistant/images/"'
  '';

  meta = {
    changelog = "https://github.com/moralmunky/Home-Assistant-Mail-And-Packages/releases/tag/${version}";
    description = "The Mail and Packages integration creates sensors for supported shippers to show a snapshot of mail and packages that are scheduled to be delivered the current day.";
    homepage = "https://github.com/moralmunky/Home-Assistant-Mail-And-Packages";
    maintainers = [ ];
  };
}