{ pkgs, ... }:
let
  magicattr_cust = pkgs.python3Packages.buildPythonPackage rec {
    pname = "magicattr";
    version = "0.1.6";
    format = "setuptools";

    src = pkgs.fetchFromGitHub {
      owner = "frmdstryr";
      repo = pname;
      rev = "master";
      sha256 = "sha256-FJtWU5AuunZbdlndGdfD1c9/0s7oRdoTi202pWjuAd8=";
    };

    buildInputs = with pkgs.python3Packages; [ setuptools ];
    doCheck = false;
  };

  ha-gehome = pkgs.buildHomeAssistantComponent rec {
    owner = "simbaja";
    domain = "ge_home";
    version = "v2025.5.0";

    src = pkgs.fetchFromGitHub {
      owner = owner;
      repo = "ha_gehome";
      rev = version;
      hash = "sha256-NlUkM70yvBeC5s7S5BkNxIC2GztfEq8xYrQZr4pkaGU=";
    };

    propagatedBuildInputs = with pkgs.python3Packages; [
      gehomesdk
      magicattr_cust
      slixmpp
    ];

    postPatch = ''
      substituteInPlace custom_components/ge_home/manifest.json \
        --replace '"slixmpp==1.8.3"' '"slixmpp>=1.8.3"'
    '';

    meta = {
      changelog = "https://github.com/simbaja/ha_gehome/releases/tag/${version}";
      description = "Integration for GE WiFi-enabled appliances into Home Assistant.";
      homepage = "https://github.com/simbaja/ha_gehome";
      maintainers = [ ];
    };
  };
in
{
  services.home-assistant.customComponents = [
    ha-gehome
  ];
}