{
  lib,
  pkgs,
  config,
  ...
}:
with lib;
let
  cfg = config.share.hardware.nvidia;
in
{
  imports = [ ./options.nix ];

  config = mkIf cfg.enable {
    hardware = {
      # Nvidia
      nvidia = {
        package =
          if cfg.enableBeta then
            config.boot.kernelPackages.nvidiaPackages.beta
          else
            config.boot.kernelPackages.nvidiaPackages.latest;

        # Modesetting is required.
        modesetting.enable = true;

        # Nvidia power management. Experimental, and can cause sleep/suspend to fail.
        powerManagement.enable = true;

        # Fine-grained power management. Turns off GPU when not in use.
        # Experimental and only works on modern Nvidia GPUs (Turing or newer).
        powerManagement.finegrained = false;

        # Use the NVidia open source kernel module (not to be confused with the
        # independent third-party "nouveau" open source driver).
        # Support is limited to the Turing and later architectures. Full list of 
        # supported GPUs is at: 
        # https://github.com/NVIDIA/open-gpu-kernel-modules#compatible-gpus 
        # Only available from driver 515.43.04+
        # Currently alpha-quality/buggy, so false is currently the recommended setting.
        open = cfg.enableOpen;

        # Enable the Nvidia settings menu,
        # accessible via `nvidia-settings`.
        nvidiaSettings = cfg.nvidiaSettings;
      };

      # Enable OpenGL
      graphics = {
        enable = true;
        enable32Bit = true;
      };
    };

    # Services configs
    services.xserver = {
      # Load nvidia driver for Xorg and Wayland
      videoDrivers = [ "nvidia" ];
    };

    # Virtualisation
    virtualisation.docker.enableNvidia = cfg.enableNvidiaDocker;

    hardware.nvidia-container-toolkit.enable = cfg.enableNvidiaDocker;
  };
}