{
  lib,
  vscode-utils,
  namespace,
  pkgs,
}:

let
  inherit (lib.trivial) importJSON;
  inherit (lib.${namespace}) selectVariant mkAllSources;

  versionSpec = importJSON ./version.json;
  selected = selectVariant versionSpec null null;
  vars = selected.variables or { };
  sources = mkAllSources pkgs selected;
in
vscode-utils.buildVscodeMarketplaceExtension {
  mktplcRef = {
    inherit (vars) name publisher version;
  };

  inherit (sources) vsix;

  unpackPhase = ''
    ${lib.getExe pkgs.unzip} -q $src
  '';

  meta = with lib; {
    description = "Use any remote machine with a SSH server as your development environment";
    longDescription = ''
      The Open Remote SSH extension allows you to open a remote folder on any 
      remote machine, virtual machine, or container with a running SSH server 
      and take full advantage of VS Code's feature set. This is an open-source
      alternative to Microsoft's proprietary Remote SSH extension, designed to
      work with VSCodium and other open-source VS Code variants.
      Note: This extension requires enabling proposed APIs in VSCodium/Code-OSS.
      You need to add "jeanp413.open-remote-ssh" to the "enable-proposed-api" 
      array in ~/.vscode-oss/argv.json
    '';
    homepage = "https://github.com/jeanp413/open-remote-ssh";
    changelog = "https://github.com/jeanp413/open-remote-ssh/releases";
    license = licenses.mit;
    platforms = platforms.all;
  };
}