{ pkgs, ... }:
let
  pyoverseerr = pkgs.python3Packages.buildPythonPackage rec {
    pname = "pyoverseerr";
    version = "0.1.40";
    format = "setuptools";

    src = pkgs.fetchFromGitHub {
      owner = "vaparr";
      repo = pname;
      rev = "master";
      sha256 = "sha256-sWYe6EV/IO/tGGXcnKiebb47eidIj0xnM/aZUfdZXyY=";
    };

    buildInputs = with pkgs.python3Packages; [ setuptools ];
    doCheck = false; # no tests in the PyPI tarball
  };

  ha-overseerr = pkgs.buildHomeAssistantComponent rec {
    owner = "vaparr";
    domain = "overseerr";
    version = "0.1.42";

    src = pkgs.fetchFromGitHub {
      owner = owner;
      repo = "ha-overseerr";
      rev = version;
      hash = "sha256-UvUowCgfay9aRV+iC/AQ9vvJzhGZbH+/1kVjxPFBKcI=";
    };

    propagatedBuildInputs = [
      pyoverseerr
    ];

    meta = {
      changelog = "https://github.com/vaparr/ha-overseerr/releases/tag/${version}";
      description = "The Overseerr integration monitors data from your Overseerr instance.";
      homepage = "https://github.com/vaparr/ha-overseerr";
      maintainers = [ ];
    };
  };
in
{
  services.home-assistant.customComponents = [
    ha-overseerr
  ];
}