move more stuff

share/amd/default.nix

@@ -0,0 +1,48 @@
+{ lib, pkgs, config, ... }:
+with lib;
+let
+  cfg = config.share.hardware.amd;
+in {
+  imports = [
+    ./options.nix
+  ];
+
+  config = mkIf cfg.enable {
+    boot.kernelParams = [ (if cfg.corectrl.enable then "amdgpu.ppfeaturemask=0xffffffff" else "") ];
+
+    # Configure programs
+    programs.corectrl.enable = cfg.corectrl.enable;
+
+    # Configure environment
+    environment = {
+      # Force radv
+      variables.AMD_VULKAN_ICD = "RADV";
+    };
+
+    # Hardware configs
+    hardware = {
+      # Enable OpenGL
+      opengl = {
+        enable = true;
+        driSupport = true;
+        driSupport32Bit = true;
+      };
+    };
+
+    # Configure polkit
+    security.polkit = {
+      enable = cfg.corectrl.enablePolkit;
+      extraConfig = ''
+        polkit.addRule(function(action, subject) {
+          if ((action.id == "org.corectrl.helper.init" ||
+              action.id == "org.corectrl.helperkiller.init") &&
+              subject.local == true &&
+              subject.active == true &&
+              subject.isInGroup("${cfg.corectrl.polkitGroup}")) {
+                  return polkit.Result.YES;
+          }
+        });
+    '';
+    };
+  };
+}

share/amd/options.nix

@@ -0,0 +1,22 @@
+{ lib, ... }:
+with lib;
+{
+  options.share.hardware.amd = {
+    enable = mkEnableOption "amd hardware config";
+    
+    corectrl.enable = mkOption {
+      type = types.bool;
+      default = false;
+    };
+
+    corectrl.enablePolkit = mkOption {
+      type = types.bool;
+      default = false;
+    };
+
+    corectrl.polkitGroup = mkOption {
+      type = types.str;
+      default = "wheel";
+    };
+  };
+}

share/default.nix

@@ -0,0 +1,7 @@
+{ ... }:
+{
+  imports = [
+    ./amd
+    ./nvidia
+  ];
+}

share/impermanence/default.nix

@@ -0,0 +1,20 @@
+{ pkgs, lib, LT, config, utils, inputs, ... }@args:
+{
+  # Set up impernance configuration for things like bluetooth
+  # In this configuration with /etc and /var/log being persistent, only directories outside of that need to be done here. See hardware configuration for all mountpoints.
+
+  environment.persistence."/nix/persist/system" = {
+    hideMounts = true;
+    directories = [
+      "/var/lib/bluetooth"
+      "/var/lib/nixos"
+      "/var/lib/systemd/coredump"
+      "/etc/NetworkManager/system-connections"
+      "/etc/secureboot"
+      { directory = "/var/lib/colord"; user = "colord"; group = "colord"; mode = "u=rwx,g=rx,o="; }
+    ];
+    files = [
+      { file = "/etc/nix/id_rsa"; parentDirectory = { mode = "u=rwx,g=,o="; }; }
+    ];
+  };
+}

share/nvidia/default.nix

@@ -0,0 +1,59 @@
+{ lib, pkgs, config, ... }:
+with lib;
+let
+  cfg = config.share.hardware.nvidia;
+in {
+  imports = [
+    ./options.nix
+  ];
+
+  config = mkIf cfg.enable {
+    hardware = {
+      # Nvidia
+      nvidia = {
+        package = if cfg.enableBeta then config.boot.kernelPackages.nvidiaPackages.beta else config.boot.kernelPackages.nvidiaPackages.latest;
+        
+        # Modesetting is required.
+        modesetting.enable = true;
+
+        # Nvidia power management. Experimental, and can cause sleep/suspend to fail.
+        powerManagement.enable = false;
+
+        # Fine-grained power management. Turns off GPU when not in use.
+        # Experimental and only works on modern Nvidia GPUs (Turing or newer).
+        powerManagement.finegrained = false;
+
+        # Use the NVidia open source kernel module (not to be confused with the
+        # independent third-party "nouveau" open source driver).
+        # Support is limited to the Turing and later architectures. Full list of 
+        # supported GPUs is at: 
+        # https://github.com/NVIDIA/open-gpu-kernel-modules#compatible-gpus 
+        # Only available from driver 515.43.04+
+        # Currently alpha-quality/buggy, so false is currently the recommended setting.
+        open = cfg.enableOpen;
+
+        # Enable the Nvidia settings menu,
+        # accessible via `nvidia-settings`.
+        nvidiaSettings = cfg.nvidiaSettings;
+      };
+      
+      # Enable OpenGL
+      opengl = {
+        enable = true;
+        driSupport = true;
+        driSupport32Bit = true;
+      };
+    };
+
+
+    # Services configs
+    services.xserver = {
+      # Load nvidia driver for Xorg and Wayland
+      videoDrivers = ["nvidia"];
+    };
+
+
+    # Virtualisation
+    virtualisation.docker.enableNvidia = cfg.enableNvidiaDocker;
+  };
+}

share/nvidia/options.nix

@@ -0,0 +1,27 @@
+{ lib, ... }:
+with lib;
+{
+  options.share.hardware.nvidia = {
+    enable = mkEnableOption "nvidia hardware config";
+    
+    enableOpen = mkOption {
+      type = types.bool;
+      default = false;
+    };
+
+    nvidiaSettings = mkOption {
+      type = types.bool;
+      default = false;
+    };
+
+    enableBeta = mkOption {
+      type = types.bool;
+      default = false;
+    };
+
+    enableNvidiaDocker = mkOption {
+      type = types.bool;
+      default = false;
+    };
+  };
+}