update hass components

modules/homeassistant/hacs/anycubic.nix

@@ -0,0 +1,47 @@
+{ pkgs, ... }:
+let
+  uart-wifi = pkgs.python3Packages.buildPythonPackage rec {
+    pname = "uart-wifi";
+    version = "0.2.1";
+    format = "pyproject";
+    src = pkgs.fetchPypi {
+      inherit pname version;
+      sha256 = "sha256-yquZ5V8f+EqetCf0nc9WlhHhnHkOASYRuYvqEIMc5HI=";
+    };
+
+    buildInputs = with pkgs.python3Packages; [ setuptools ];
+
+    doCheck = false; # no tests in the PyPI tarball
+  };
+
+  ha-anycubic = pkgs.buildHomeAssistantComponent rec {
+    owner = "adamoutler";
+    domain = "anycubic_wifi";
+    version = "HACS-10";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "anycubic-homeassistant";
+      rev = version;
+      hash = "sha256-TfZadwgdEJR11MaL+nfIgEYld3trWg3v6lOHSoxQ98Q=";
+    };
+
+    # PYTHONPATH = [ "${src}/uart-wifi" ];
+
+    propagatedBuildInputs = [
+      uart-wifi
+    ];
+
+    meta = {
+      changelog = "https://github.com/adamoutler/anycubic-homeassistant/releases/tag/${version}";
+      description = "This is a library to provide support for Mono X Printers.";
+      homepage = "https://github.com/adamoutler/anycubic-homeassistant";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-anycubic
+  ];
+}

modules/homeassistant/hacs/bambulab.nix

@@ -0,0 +1,31 @@
+{ pkgs, ... }:
+let
+  ha-bambulab = pkgs.buildHomeAssistantComponent rec {
+    owner = "greghesp";
+    domain = "bambu_lab";
+    version = "v2.1.27";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "ha-bambulab";
+      rev = version;
+      hash = "sha256-zHPXPYsHrJXOnSqllZqDrxGZDDqyXllC3XEGZRJil0Q=";
+    };
+
+    propagatedBuildInputs = with pkgs.python3Packages; [
+      beautifulsoup4
+    ];
+
+    meta = {
+      changelog = "https://github.com/greghesp/ha-bambulab/releases/tag/${version}";
+      description = "A Home Assistant Integration for Bambu Lab printers.";
+      homepage = "https://github.com/greghesp/ha-bambulab";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-bambulab
+  ];
+}

modules/homeassistant/hacs/default.nix

@@ -0,0 +1,14 @@
+{ ... }:
+{
+  imports = [
+    ./anycubic.nix
+    ./bambulab.nix
+    ./gehome.nix
+    ./icloud3.nix
+    ./mail-and-packages.nix
+    ./nanokvm.nix
+    ./overseerr.nix
+    ./petlibro.nix
+    ./wyzeapi.nix
+  ];
+}

modules/homeassistant/hacs/gehome.nix

@@ -0,0 +1,54 @@
+{ pkgs, ... }:
+let
+  magicattr_cust = pkgs.python3Packages.buildPythonPackage rec {
+    pname = "magicattr";
+    version = "0.1.6";
+    format = "setuptools";
+
+    src = pkgs.fetchFromGitHub {
+      owner = "frmdstryr";
+      repo = pname;
+      rev = "master";
+      sha256 = "sha256-FJtWU5AuunZbdlndGdfD1c9/0s7oRdoTi202pWjuAd8=";
+    };
+
+    buildInputs = with pkgs.python3Packages; [ setuptools ];
+    doCheck = false;
+  };
+
+  ha-gehome = pkgs.buildHomeAssistantComponent rec {
+    owner = "simbaja";
+    domain = "ge_home";
+    version = "v2025.5.0";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = domain;
+      rev = version;
+      hash = "sha256-NlUkM70yvBeC5s7S5BkNxIC2GztfEq8xYrQZr4pkaGU=";
+    };
+
+    propagatedBuildInputs = with pkgs.python3Packages; [
+      gehomesdk
+      magicattr_cust
+      slixmpp
+    ];
+
+    postPatch = ''
+      substituteInPlace custom_components/ge_home/manifest.json \
+        --replace '"slixmpp==1.8.3"' '"slixmpp>=1.8.3"'
+    '';
+
+    meta = {
+      changelog = "https://github.com/simbaja/ha_gehome/releases/tag/${version}";
+      description = "Integration for GE WiFi-enabled appliances into Home Assistant.";
+      homepage = "https://github.com/simbaja/ha_gehome";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-gehome
+  ];
+}

modules/homeassistant/hacs/icloud3.nix

@@ -0,0 +1,31 @@
+{ pkgs, ... }:
+let
+  ha-icloud3 = pkgs.buildHomeAssistantComponent rec {
+    owner = "gcobb321";
+    domain = "icloud3";
+    version = "3.2.2.3";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "icloud3";
+      rev = "v.${version}";
+      hash = "sha256-OjXioS73jE/U2YeKYf84QnStdQj3Seid4hJ2TH6z13M=";
+    };
+
+    propagatedBuildInputs = with pkgs.python3Packages; [
+      srp
+    ];
+
+    meta = {
+      changelog = "https://github.com/gcobb321/icloud3/releases/tag/${version}";
+      description = "Cloud3 is a device tracker custom component that tracks your iPhones, iPads and Apple Watches. Devices in the Family Sharing List and the HA Mobile App Integration are trackable.";
+      homepage = "https://github.com/gcobb321/icloud3";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-icloud3
+  ];
+}

modules/homeassistant/hacs/mail-and-packages.nix

@@ -0,0 +1,33 @@
+{ pkgs, ... }:
+let
+  ha-mail-and-packages = pkgs.buildHomeAssistantComponent rec {
+    owner = "moralmunky";
+    domain = "mail_and_packages";
+    version = "0.4.2";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "Home-Assistant-Mail-And-Packages";
+      rev = version;
+      hash = "sha256-5LBTlRlkSUx8DOY+F7UvUs4dzjZKdBdgnDUdK6DBdew=";
+    };
+
+    propagatedBuildInputs = with pkgs.python3Packages; [
+      beautifulsoup4
+      dateparser
+      pillow
+    ];
+
+    meta = {
+      changelog = "https://github.com/moralmunky/Home-Assistant-Mail-And-Packages/releases/tag/${version}";
+      description = "The Mail and Packages integration creates sensors for supported shippers to show a snapshot of mail and packages that are scheduled to be delivered the current day.";
+      homepage = "https://github.com/moralmunky/Home-Assistant-Mail-And-Packages";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-mail-and-packages
+  ];
+}

modules/homeassistant/hacs/nanokvm.nix

@@ -0,0 +1,59 @@
+{ pkgs, ... }:
+let
+  python-nanokvm = pkgs.python3Packages.buildPythonPackage rec {
+    pname = "python-nanokvm";
+    version = "v0.0.3";
+    format = "pyproject";
+
+    src = pkgs.fetchFromGitHub {
+      owner = "puddly";
+      repo = pname;
+      rev = version;
+      sha256 = "sha256-jBBd+O3S/4AlxAhrF9j9Bi5vMKZNk0M17ok9JzcI8F8=";
+    };
+
+    buildInputs = with pkgs.python3Packages; [ 
+      setuptools
+      setuptools-git-versioning
+    ];
+
+    nativeBuildInputs = with pkgs.python3Packages; [
+      aiohttp
+      cryptography
+      yarl
+      pillow
+      pydantic
+    ];
+
+    doCheck = false;
+  };
+
+  ha-nanokvm = pkgs.buildHomeAssistantComponent rec {
+    owner = "Wouter0100";
+    domain = "nanokvm";
+    version = "v0.0.1";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "homeassistant-nanokvm";
+      rev = "663f9710dfea109f0bb0417df5828b8d639e70c4";
+      hash = "sha256-6rTEOshNCe0x4iEHljqY/6p2TK1HasgNycRHkmo2Hhw=";
+    };
+
+    propagatedBuildInputs = [
+      python-nanokvm
+    ];
+
+    meta = {
+      changelog = "https://github.com/Wouter0100/homeassistant-nanokvm/releases/tag/${version}";
+      description = "This integration allows you to control and monitor your Sipeed NanoKVM device from Home Assistant.";
+      homepage = "https://github.com/Wouter0100/homeassistant-nanokvm";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-nanokvm
+  ];
+}

modules/homeassistant/hacs/overseerr.nix

@@ -0,0 +1,47 @@
+{ pkgs, ... }:
+let
+  pyoverseerr = pkgs.python3Packages.buildPythonPackage rec {
+    pname = "pyoverseerr";
+    version = "0.1.40";
+    format = "setuptools";
+
+    src = pkgs.fetchFromGitHub {
+      owner = "vaparr";
+      repo = pname;
+      rev = "master";
+      sha256 = "sha256-sWYe6EV/IO/tGGXcnKiebb47eidIj0xnM/aZUfdZXyY=";
+    };
+
+    buildInputs = with pkgs.python3Packages; [ setuptools ];
+    doCheck = false; # no tests in the PyPI tarball
+  };
+
+  ha-overseerr = pkgs.buildHomeAssistantComponent rec {
+    owner = "vaparr";
+    domain = "overseerr";
+    version = "0.1.42";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "ha-overseerr";
+      rev = version;
+      hash = "sha256-UvUowCgfay9aRV+iC/AQ9vvJzhGZbH+/1kVjxPFBKcI=";
+    };
+
+    propagatedBuildInputs = [
+      pyoverseerr
+    ];
+
+    meta = {
+      changelog = "https://github.com/vaparr/ha-overseerr/releases/tag/${version}";
+      description = "The Overseerr integration monitors data from your Overseerr instance.";
+      homepage = "https://github.com/vaparr/ha-overseerr";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-overseerr
+  ];
+}

modules/homeassistant/hacs/petlibro.nix

@@ -0,0 +1,27 @@
+{ pkgs, ... }:
+let
+  ha-petlibro = pkgs.buildHomeAssistantComponent rec {
+    owner = "jjjonesjr33";
+    domain = "petlibro";
+    version = "v1.0.22.3";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "petlibro";
+      rev = version;
+      hash = "sha256-fYzy4OpK9Fs+KQ44H4G6DJlcSg9Zyi56fjsmdxDBviM=";
+    };
+
+    meta = {
+      changelog = "https://github.com/jjjonesjr33/petlibro/releases/tag/${version}";
+      description = "PETLIBRO integration for Home Assistant.";
+      homepage = "https://github.com/jjjonesjr33/petlibro";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-petlibro
+  ];
+}

modules/homeassistant/hacs/wyzeapi.nix

@@ -0,0 +1,59 @@
+{ pkgs, ... }:
+let
+  wyzeapy = pkgs.python3Packages.buildPythonPackage rec {
+    pname = "wyzeapy";
+    version = "0.5.27";
+    format = "pyproject";
+
+    src = pkgs.fetchFromGitHub {
+      owner = "SecKatie";
+      repo = "wyzeapy";
+      rev = version;
+      sha256 = "sha256-IfhRsVWj/bcKOtpCdmpgrz3L8iY73e+weHlOo5rfKHw=";
+    };
+
+    buildInputs = with pkgs.python3Packages; [ poetry-core ];
+
+    nativeBuildInputs = with pkgs.python3Packages; [ 
+      aiodns
+      aiohttp
+      pycryptodome
+    ];
+
+    doCheck = false; # no tests in the PyPI tarball
+  };
+
+  ha-wyzeapi = pkgs.buildHomeAssistantComponent rec {
+    owner = "SecKatie";
+    domain = "wyzeapi";
+    version = "0.1.33";
+
+    src = pkgs.fetchFromGitHub {
+      owner = owner;
+      repo = "ha-wyzeapi";
+      rev = version;
+      hash = "sha256-Hl1Vmi2lhoJW3bdkrtO2mNqfLxURPwqFPjYgdrHRxYk=";
+    };
+
+    propagatedBuildInputs = [
+      wyzeapy
+    ];
+
+    postPatch = ''
+      substituteInPlace custom_components/wyzeapi/manifest.json \
+        --replace '"wyzeapy>=0.5.28,<0.6"' '"wyzeapy>=0.5.27,<0.6"'
+    '';
+
+    meta = {
+      changelog = "https://github.com/SecKatie/ha-wyzeapi/releases/tag/${version}";
+      description = "This is a custom component to allow control of various Wyze devices in Home Assistant using the unofficial API.";
+      homepage = "https://github.com/SecKatie/ha-wyzeapi";
+      maintainers = [ ];
+    };
+  };
+in
+{
+  services.home-assistant.customComponents = [
+    ha-wyzeapi
+  ];
+}