{
  # ccacheStdenv,
  stdenv,
  lib,
  fetchFromGitHub,
  buildLinux,
  rpiVersion ? 5,
  ...
}@args:

let
  # stdenv = ccacheStdenv;
  modDirVersion = "6.12.47";
  tag = "stable_20250916";
  hash = "sha256-HG8Oc04V2t54l0SOn4gKmNJWQUrZfjWusgKcWvx74H0==";
  # NOTE: raspberrypifw & raspberryPiWirelessFirmware should be updated with this

  # all of these fail for various reasons

  # tag = "unstable_20260116";

  # modDirVersion = "6.15.11";
  # hash = "sha256-25g+LkVJMixVwUf+MRoIvLkVj31sFGAK9+i3OEFkFc0=";
  # rev = "b07d612aae961e99fdb0b828ce6d54c183d1833d";

  # modDirVersion = "6.17.12";
  # hash = "sha256-JcjRy1FbOPWqqxKe/BjzMJBStA7rjK4+pS8kqL9GZBg=";
  # rev = "682dc10883eefbcbc4a5ec661b231a638192b98f";

  # modDirVersion = "6.18.4";
  # hash = "sha256-T3RJRroYtzLwx4JqcaX15Ka1uVf72jQOZMf7TJVZ6co=";
  # rev = "bb594fb36f555f9b88b7b6fcf8b71c669c1d60c7";

  # modDirVersion = "6.19.0-rc5";
  # hash = "sha256-C81aKv+pQYNx6Bj3PL0vrxvBzrLB99+95YeIBm+4kt0=";
  # rev = "12e23f26704f66c154de58f80222960f02885570";
in
lib.overrideDerivation
  (buildLinux (
    args
    // {
      version = "${modDirVersion}-${tag}";
      inherit modDirVersion;
      pname = "linux-rpi${toString rpiVersion}";

      src = fetchFromGitHub {
        owner = "raspberrypi";
        repo = "linux";
        inherit tag hash;
      };

      defconfig =
        {
          "1" = "bcmrpi_defconfig";
          "2" = "bcm2709_defconfig";
          "3" = if stdenv.hostPlatform.isAarch64 then "bcm2711_defconfig" else "bcm2709_defconfig";
          "4" = "bcm2711_defconfig";
          "5" = "bcm2712_defconfig";
        }
        .${toString rpiVersion};

      features = {
        efiBootStub = false;
      }
      // (args.features or { });

      isLTS = true;

      structuredExtraConfig = lib.mkIf (rpiVersion == 5) (
        with lib.kernel;
        {
          CONFIG_ARM64_4K_PAGES = lib.mkForce no;
          CONFIG_ARM64_64K_PAGES = lib.mkForce no;
          CONFIG_ARM64_16K_PAGES = lib.mkForce yes;
        }
      );

      extraMakeFlags = [ "KCFLAGS=-Wno-error" ];

      extraMeta =
        if (rpiVersion < 3) then
          {
            platforms = with lib.platforms; lib.intersectLists arm linux;
            hydraPlatforms = [ ];
          }
        else if (rpiVersion == 5) then
          {
            platforms = with lib.platforms; lib.intersectLists aarch64 linux;
            hydraPlatforms = [ "aarch64-linux" ];
          }
        else
          {
            platforms = with lib.platforms; lib.intersectLists (arm ++ aarch64) linux;
            hydraPlatforms = [ "aarch64-linux" ];
          };
      ignoreConfigErrors = true;
    }
    // (args.argsOverride or { })
  ))
  (_oldAttrs: {
    postConfigure = ''
      # The v7 defconfig has this set to '-v7' which screws up our modDirVersion.
      sed -i $buildRoot/.config -e 's/^CONFIG_LOCALVERSION=.*/CONFIG_LOCALVERSION=""/'
      sed -i $buildRoot/include/config/auto.conf -e 's/^CONFIG_LOCALVERSION=.*/CONFIG_LOCALVERSION=""/'
    '';

    # Make copies of the DTBs named after the upstream names so that U-Boot finds them.
    # This is ugly as heck, but I don't know a better solution so far.
    postFixup = ''
      dtbDir=${if stdenv.hostPlatform.isAarch64 then "$out/dtbs/broadcom" else "$out/dtbs"}
      rm $dtbDir/bcm283*.dtb
      copyDTB() {
        cp -v "$dtbDir/$1" "$dtbDir/$2"
      }
    ''
    + lib.optionalString (lib.elem stdenv.hostPlatform.system [ "armv6l-linux" ]) ''
      copyDTB bcm2708-rpi-zero-w.dtb bcm2835-rpi-zero.dtb
      copyDTB bcm2708-rpi-zero-w.dtb bcm2835-rpi-zero-w.dtb
      copyDTB bcm2708-rpi-b.dtb bcm2835-rpi-a.dtb
      copyDTB bcm2708-rpi-b.dtb bcm2835-rpi-b.dtb
      copyDTB bcm2708-rpi-b.dtb bcm2835-rpi-b-rev2.dtb
      copyDTB bcm2708-rpi-b-plus.dtb bcm2835-rpi-a-plus.dtb
      copyDTB bcm2708-rpi-b-plus.dtb bcm2835-rpi-b-plus.dtb
      copyDTB bcm2708-rpi-b-plus.dtb bcm2835-rpi-zero.dtb
      copyDTB bcm2708-rpi-cm.dtb bcm2835-rpi-cm.dtb
    ''
    + lib.optionalString (lib.elem stdenv.hostPlatform.system [ "armv7l-linux" ]) ''
      copyDTB bcm2709-rpi-2-b.dtb bcm2836-rpi-2-b.dtb
    ''
    +
      lib.optionalString
        (lib.elem stdenv.hostPlatform.system [
          "armv7l-linux"
          "aarch64-linux"
        ])
        ''
          copyDTB bcm2710-rpi-zero-2.dtb bcm2837-rpi-zero-2.dtb
          copyDTB bcm2710-rpi-zero-2-w.dtb bcm2837-rpi-zero-2-w.dtb
          copyDTB bcm2710-rpi-3-b.dtb bcm2837-rpi-3-b.dtb
          copyDTB bcm2710-rpi-3-b-plus.dtb bcm2837-rpi-3-a-plus.dtb
          copyDTB bcm2710-rpi-3-b-plus.dtb bcm2837-rpi-3-b-plus.dtb
          copyDTB bcm2710-rpi-cm3.dtb bcm2837-rpi-cm3.dtb
          copyDTB bcm2711-rpi-4-b.dtb bcm2838-rpi-4-b.dtb
          copyDTB bcm2712-rpi-5-b.dtb bcm2839-rpi-5-b.dtb
        '';
  })
